Description

mididefault is designed to simplify writing instruments that can be used interchangeably for either score or MIDI input, and to make it easier to adapt instruments originally written for score input to work with MIDI input.

In general, it should be possible to write instrument definitions that work identically with both scores and MIDI, including both MIDI files and real-time MIDI input, without using any conditional statements, and that take full advantage of MIDI voice messages.

Note that correlating Csound instruments with MIDI channel numbers is done using the massign opcode for real-time performance,. For file-driven performance, instrument numbers default to MIDI channel number + 1, but the defaults are overridden by any MIDI program change messages in the file.

Syntax

mididefault xdefault, xvalue

Performance

xdefault -- specifies a default value that will be used during MIDI activation.

xvalue -- overwritten by xdefault during MIDI activation, remains unchanged otherwise.

If the instrument was activated by MIDI input, the opcode will overwrite the value of xvalue with the value of xdefault. If the instrument was NOT activated by MIDI input, xvalue will remain unchanged.

This enables score pfields to receive a default value during MIDI activation, and score values otherwise.

	Adapting a score-activated Csound instrument.
	See the MIDI interop opcodes section for details on adapting score driven instruments for MIDI or vice-versa.

Examples

Here is an example of the mididefault opcode. Play mididefault.csd

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac    -M1  ;;;realtime audio out and midi in 
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o mididefault.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

mididefault 60, p3					;ensures that a MIDI-activated instrument will have a positive p3 field
midinoteoncps p4, p5					;puts MIDI key translated to cycles per second into p4, and MIDI velocity into p5

kvel = p5/127						;scale midi velocity to 0-1
kenv madsr 0.5, 0.8, 0.8, 0.5				;amplitude envelope multiplied by
asig pluck kenv*kvel, p4, p4, 2, 1			;velocity		
     outs  asig, asig

endin
</CsInstruments>
<CsScore>
f 0 30	;runs for 30 seconds
f 2 0 4096 10 1	

i 1 0 2 440 100	; play these notes from score as well
i 1 + 2 1440 100
e

</CsScore>
</CsoundSynthesizer>

See Also

midichannelaftertouch, midicontrolchange, midinoteoff, midinoteoncps, midinoteonkey, midinoteonoct, midinoteonpch, midipitchbend, midipolyaftertouch, midiprogramchange

Credits

Author: Michael Gogins

New in version 4.20