Description

Mvclpf4 is an digital implementation of the 4th-order (24 dB/oct) Moog ladder filter originally written by Fons Andriaensen. It is a version of the mvclpf3 opcode with four outputs, for 6dB, 12dB, 18dB, and 24 dB/octave responses.

Syntax

asig1,asig2,asig3,asig4 mvclpf4 ain, xcf, xres[, istor]

Initialization

istor --initial disposition of internal data space. Since filtering incorporates a feedback loop of previous output, the initial status of the storage space used is significant. A zero value will clear the space; a non-zero value will allow previous information to remain. The default value is 0.

Performance

asig1 -- 6dB/oct low-pass response output.

asig2 -- 12dB/oct low-pass response output.

asig3 -- 18dB/oct low-pass response output..

asig4 -- 24dB/oct low-pass response output.

ain -- input signal.

xcf -- filter cutoff frequency. The useful range is around six octaves below and above middle C (pch 8.00).

xres -- resonance, limited to the interval [0,1].

Examples

Here is an example of the mvclpf4 opcode. Play mvclpf4.csd

<CsoundSynthesizer>
<CsOptions>
-odac 
</CsOptions>
<CsInstruments>
0dbfs = 1

instr 1
 asig[] init 4
 kenv linen p4,0.1,p3,0.1
 ain rand kenv 
 kfr expon 220, p3, 1760
 asig[0],asig[1],asig[2],asig[3] mvclpf4 ain,kfr,0.9
  out asig[p5]
endin

</CsInstruments>
<CsScore>
i1 0 5 0.9 0
i1 + 5 0.9 1
i1 + 5 0.9 2
i1 + 5 0.9 3
</CsScore>
</CsoundSynthesizer>

Credits

New in version 6.07

January 2016.