pvsinit
Prev  Orchestra Opcodes and Operators  Next

pvsinit

pvsinit — Initialise a spectral (f) variable to zero.

Description

Performs the equivalent to an init operation on an f-variable.

Syntax

fsig pvsinit isize[, iolap, iwinsize, iwintype, iformat]

Performance

fsig -- output pv stream set to zero.

isize -- size of the DFT frame.

iolap -- size of the analysis overlap, defaults to isize/4.

iwinsize -- size of the analysis window, defaults to isize.

iwintype -- type of analysis window, defaults to 1, Hanning.

iformat -- pvsdata format, defaults to 0:PVS_AMP_FREQ.

Examples

Here is an example of the pvsinit opcode. Play pvsinit.csd

Example 842. Example of the pvsinit opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac    ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
;-o pvsinit.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; by Victor Lazzarini

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

gfsig pvsinit 1024,256,1024,1

instr 1

a1  diskin p4
fs1 pvsanal a1,1024,256,1024,1
gfsig pvsmix fs1,gfsig
endin

instr 2
a1  pvsynth gfsig
outs a1, a1
; clear fsig
gfsig pvsgain gfsig,0
endin

</CsInstruments>
<CsScore>
i1 0 4 "fox.wav"
i1 0 4  "beats.wav"
i2 0 4
</CsScore>
</CsoundSynthesizer>


Credits

Author: Victor Lazzarini
November 2004

New plugin in version 5

November 2004.

Prev  Up  Next
pvsinfo  Home  pvsin