Description

A resonant low-pass filter.

Syntax

ares rezzy asig, xfco, xres [, imode, iskip]

Initialization

imode (optional, default=0) -- high-pass or low-pass mode. If zero, rezzy is low-pass. If not zero, rezzy is high-pass. Default value is 0. (New in Csound version 3.50)

iskip (optional, default=0) -- if non zero skip the initialisation of the filter. (New in Csound version 4.23f13 and 5.0)

Performance

asig -- input signal

xfco -- filter cut-off frequency in Hz. As of version 3.50, may i-,k-, or a-rate.

xres -- amount of resonance. Values of 1 to 100 are typical. Resonance should be one or greater. As of version 3.50, may a-rate, i-rate, or k-rate.

rezzy is a resonant low-pass filter created empirically by Hans Mikelson.

Examples

Here is an example of the rezzy opcode. Play rezzy.csd

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac   ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o rezzy.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
0dbfs  = 1
nchnls = 2

instr 1

asaw vco2 .3, 110	;sawtooth
kcf  line 1760, p3, 220	;vary cut-off frequency from 220 to 1280 Hz
kres = p4		;vary resonance too
ares rezzy asaw, kcf, kres
asig balance ares, asaw
     outs asig, asig

endin
</CsInstruments>
<CsScore>

i 1 0 4 10
i 1 + 4 30
i 1 + 4 120	;lots of resonance
e
</CsScore>
</CsoundSynthesizer>

See Also

biquad, moogvcf

Credits

New in Csound version 3.49